@echo off
chcp 65001 >nul
title Installation RadReport pour Word
echo.
echo  ==============================================
echo    Installation du complement RadReport pour Word
echo  ==============================================
echo.
echo  Fermez Word (enregistrez vos documents) avant de continuer.
pause
set RRDIR=%LOCALAPPDATA%\RadReport
echo  [1/4] Dossier %RRDIR%
if not exist "%RRDIR%" mkdir "%RRDIR%"
echo  [2/4] Telechargement du complement depuis radreport.fr
powershell -NoProfile -ExecutionPolicy Bypass -Command "[Net.ServicePointManager]::SecurityProtocol=[Net.SecurityProtocolType]::Tls12; Invoke-WebRequest -Uri 'https://radreport.fr/word/manifest.xml' -OutFile ($env:LOCALAPPDATA + '\RadReport\RadReport-Word.xml') -UseBasicParsing"
if not exist "%RRDIR%\RadReport-Word.xml" (
  echo  ERREUR : telechargement impossible. Verifiez la connexion internet.
  pause
  exit /b 1
)
rem Cache des complements Office : Word y garde lancienne version du manifeste (22 oct 2026)
if exist "%LOCALAPPDATA%\Microsoft\Office\16.0\Wef" rmdir /s /q "%LOCALAPPDATA%\Microsoft\Office\16.0\Wef" >nul 2>&1
echo  [3/4] Declaration du complement dans Word
reg add "HKCU\Software\Microsoft\Office\16.0\WEF\Developer" /v "20c7ae4a-b3de-492a-bc42-67f7f65b2c6d" /t REG_SZ /d "%RRDIR%\RadReport-Word.xml" /f >nul
if errorlevel 1 (
  echo  ERREUR : impossible d'ecrire le reglage Word.
  pause
  exit /b 1
)
echo  [4/4] Module RadReport pour les documents RTF (dossier de demarrage de Word)
set RRSTART=%APPDATA%\Microsoft\Word\STARTUP
if not exist "%RRSTART%" mkdir "%RRSTART%"
powershell -NoProfile -ExecutionPolicy Bypass -Command "[Net.ServicePointManager]::SecurityProtocol=[Net.SecurityProtocolType]::Tls12; try { Invoke-WebRequest -Uri 'https://radreport.fr/media/RadReport.dotm' -OutFile ($env:APPDATA + '\Microsoft\Word\STARTUP\RadReport.dotm') -UseBasicParsing } catch { exit 1 }"
if errorlevel 1 (
  echo  Module RTF non installe pour l'instant ^(le complement principal fonctionne^).
) else (
  echo  Module RTF installe : onglet RadReport dans le ruban de Word.
)
echo.
echo  Termine. Dans Word :
echo.
echo    1. Fermez Word completement, puis rouvrez-le.
echo    2. Le bouton RadReport apparait dans l'onglet Accueil.
echo       Sinon : Insertion ^> Complements ^> Mes complements ^> RadReport.
echo    3. Fichiers RTF ou "Mode de compatibilite" : utilisez l'onglet RadReport
echo       du ruban (Structurer, Dernier CR, Panneau).
echo.
pause